Bool'sche Wahrheitstafel - Listing

Dokumentation ansehen
Programmspeicher-Image laden

10	"B" CLS :CLEAR :WAIT 0:PRINT "Funktionen Z(A,B,C...) ,":PRINT "Y(A,B,C...),usw. in den"
20	WAIT :PRINT "Zeilen 90ff. eingegeben?"
30	CLS :INPUT "Eingaenge: ";K,"Ausgaenge: ";L:DIM Z$(0)*(K+L+3)
40	FOR M=1 TO K:Z$(0)=Z$(0)+CHR$ (64+M):NEXT M:Z$(0)=Z$(0)+" ! ":FOR M=L TO 1 STEP -1
50	Z$(0)=Z$(0)+CHR$ (91-M):NEXT M:PRINT =LPRINT :PRINT "":PRINT "Wahrheitstafel"
60	PRINT "":PRINT Z$(0):Z$(0)=""
70	Z$(0)=LEFT$ ("------------------------",L+K+3)
80	FOR N=0 TO 2^K-1:O=N:FOR P=K-1 TO 0 STEP -1:A(K-P)=INT (O/2^P):O=O-A(K-P)*2^P:NEXT P
90	Z=A AND B AND C
91	Y=A OR B OR C
92	X=NOT (A AND B AND C)
93	W=NOT (A OR B OR C)
94	V=A OR B AND C
95	U=A OR (B AND C)
200	FOR M=27-L TO 26:A(M)=ABS A(M):IF A(M)=2 LET A(M)=0
210	NEXT M
220	FOR M=1 TO K:Z$(0)=Z$(0)+STR$ A(M):NEXT M:Z$(0)=Z$(0)+" ! "
230	FOR M=27-L TO 26:Z$(0)=Z$(0)+STR$ A(M):NEXT M:PRINT Z$(0):Z$(0)="":NEXT N
240	PRINT =PRINT
250	END

Dokumentation ansehen
Programmspeicher-Image laden