Sharp PC1360 Taschencomputer
 

 Sharp PC1360

Komplexe Zahlen - Listing


Dokumentation ansehen
Programmspeicher-Image laden


10 "Z" RADIAN :WAIT 0:CLEAR
20 PRINT "Eingabeform :":PRINT "K(omponenten)":PRINT "E(xponential)":INPUT E$
30 GOSUB E$+"I":CLS :PRINT "":PRINT " *** BUSY ***"
40 GOSUB O$:CLS
50 U=INT (U*1E6+.5)/1E6:V=INT (V*1E6+.5)/1E6:X=INT (X*1E6+.5)/1E6:W=INT (W*1E3+.5)/1E3
60 PRINT "Re = ";U:WAIT :PRINT "Im = ";V
70 IF U<>0 OR V<>0 WAIT 0:PRINT "r = ";X:WAIT :PRINT "phi = ";W;" deg"
80 WAIT 0:GOTO 20
90 END
100 "POL" Y=SQR(R*R+P*P):IF R=0 LET Z=90*SGN P:GOTO 130
110 Z=ATN (P/R)
120 IF R<0 LET Z=Z+180
130 RETURN
140 "REC" Y=R*COS P:Z=R*SIN P
150 RETURN
160 "TRI" R=A:P=B:GOSUB "REC":A=Y:B=Z
170 RETURN
180 "KI" INPUT "Re1 = ";A,"Im1 = ";B
190 CLS :PRINT "+,-,*,/,^,SQR,LN,SIN,COS oder TAN":INPUT O$
200 IF O$="^" OR O$="SQR" OR LEN O$>1 THEN RETURN
210 INPUT "Eingabeart wie zuvor ? ";F$
220 IF LEFT$ (F$,1)="N" THEN 250
230 INPUT "Re2 = ";C,"Im2 = ";D
240 RETURN
250 INPUT "r2 = ";C,"phi2 = ";D
260 R=C:P=D:GOSUB "REC":C=Y:D=Z
270 RETURN
280 "EI" INPUT "r1 = ";A,"phi1 = ";B
290 CLS :PRINT "+,-,*,/,^,SQR,LN,SIN,COS oder TAN":INPUT O$
300 IF O$="SQR" OR O$="^" OR LEN O$>1 THEN RETURN
310 INPUT "Eingabeart wie zuvor ? ";F$
320 IF LEFT$ (F$,1)="N" THEN 350
330 INPUT "r2 = ";C,"phi2 = ";D
340 RETURN
350 INPUT "Re2 = ";C,"Im2 = ";D
360 R=C:P=D:GOSUB "POL":C=Y:D=Z
370 RETURN
380 "SQR" N=.5:GOTO 400
390 "^" INPUT "Exponent : ";N
400 IF E$="K" LET R=A:P=B:GOSUB "POL":A=Y:B=Z
410 X=A^N:W=B*N:R=X:P=W:GOSUB "REC":U=Y:V=Z
420 RETURN
430 "+"
440 "-" IF E$="E" GOSUB "TRI":R=C:P=D:GOSUB "REC":C=Y:D=Z
450 IF O$="-" LET C=-C:D=-D
460 U=A+C:V=B+D
470 R=U:P=V:GOSUB "POL":X=Y:W=Z
480 RETURN
490 "*"
500 "/" IF E$="K" LET R=A:P=B:GOSUB "POL":A=Y:B=Z:R=C:P=D:GOSUB "POL":C=Y:D=Z
510 IF O$="/" LET C=1/C:D=-D
520 X=A*C:W=B+D:R=X:P=W:GOSUB "REC":U=Y:V=Z
530 RETURN
540 "LN" IF E$="K" LET R=A:P=B:GOSUB "POL":A=Y:B=Z
550 U=LN ABS A:V=B*PI /180:R=U:P=V:GOSUB "POL":X=Y:W=Z
560 RETURN
570 "SIN" IF E$="E" GOSUB "TRI"
580 U=SIN A*.5*(EXP B+EXP -B):V=COS A*.5*(EXP B-EXP -B)
590 R=U:P=V:GOSUB "POL":X=Y:W=Z:RETURN
600 X=0:W=0
610 RETURN
620 "COS" IF O$="TAN" THEN 640
630 IF E$="E" GOSUB "TRI"
640 U=COS A*.5*(EXP B+EXP -B):V=SIN A*.5*(EXP B-EXP -B)
650 R=U:P=V:GOSUB "POL":X=Y:W=Z:RETURN
660 RETURN
670 "TAN" GOSUB "SIN"
680 M=X:L=W
690 GOSUB "COS"
700 X=M/X:W=L-W
710 R=X:P=W:GOSUB "REC":U=Y:V=Z
720 RETURN


Dokumentation ansehen
Programmspeicher-Image laden



Zur Übersichtstabelle



Home
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!