Sharp PC1360 Taschencomputer
 

 Sharp PC1360

Cassettenlabel drucken - Listing


Dokumentation ansehen
Programmspeicher-Image laden


10"C"CLEAR :CLS :WAIT 0
20IF MEM$<>"C" BEEP 2:PRINT "Bitte SETMEM";CHR$ 34;"C";CHR$ 34;" eingebenund neu starten !":STOP
30DIM F$(0)*28,I$(1)*33,S$(1)*33,T$(0)*80
40T$="Cr"
50CLS :INPUT "Bandsorte: ";T$
60D$="Off":POKE 12348,16
70CLS :INPUT "Dolby ";D$
80C$="90":POKE 12348,16
90CLS :INPUT "Spieldauer: C";C$
100CLS :PRINT "Markenbezeichnung :":INPUT F$(0)
110POKE 12348,16
120IF LEN F$(0)>27 BEEP 2GOTO 100
130CLS :INPUT "Ordnungsnummer : ";O$:IF LEN O$>2BEEP 2:GOTO 130
140CLS :PRINT "Seite 1":INPUT "Titel : ";S$(0):POKE 12348,16:INPUT "Interpret: ";I$(0)
150POKE 12348,16
160IF LEN (S$(0)+I$(0))>32 BEEP 2:GOTO 140
170CLS :PRINT "Seite 2":INPUT "Titel : ";S$(1):POKE 12348,16:INPUT "Interpret: ";I$(1)
180POKE 12348,16
190IF LEN (S$(1)+I$(1))>32 BEEP 2:GOTO 170
200WAIT :CLS :PRINT "CE-140P o.k.? ":WAIT 0
210CLS
220LPRINT CHR$ &1B+"@
230GRAPH :COLOR 0,7:LLINE (480,0)-(0,0),1
240LLINE (78,-15)-(403,-15)-(480,-83)-(480,-110)-(0,-110)-(0,-83),0
250LLINE (0,-83)-(78,-15)
260GLCURSOR (90,-50):LPRINT "P";F$(0)
270GLCURSOR (90,-75):LPRINT "P";T$:GLCURSOR (240,-75):LPRINT "PC";C$
280GLCURSOR (90,-100):LPRINT "PDolby ";D$:GLCURSOR (240,-100):LPRINT "PStereo"
290LLINE (480,-125)-(0,-125),1
300LLINE (0,-135)-(46,-181),0,2,B
310CROTATE 1:CSIZE 3:COLOR 4,7
320IF LEN O$=1 GLCURSOR (14,-151):GOTO 340
330GLCURSOR (14,-142)
340LPRINT "P";O$
350CROTATE 0:CSIZE 1:LLINE (54,-135)-(69,-150),0,5
360GLCURSOR (60,-146):LPRINT "P1"
370LLINE (54,-181)-(69,-166),0,1
380GLCURSOR (60,-177):LPRINT "P2":POKE &FB20,0
390LLINE (0,-191)-(480,-191),1,0
400LLINE (480,-158)-(54,-158),0,0
410CSIZE 2:GLCURSOR (84,-150):COLOR 0,7:LPRINT "P";I$(0):COLOR 2,7:LPRINT "P ";S$(0)
420GLCURSOR (84,-181):COLOR 0,7:LPRINT "P";I$(1):COLOR 2,7:LPRINT "P ";S$(1)
430S=5:GLCURSOR (0,-191):GOSUB 650
440M=1
450CLS :PRINT "1 = Titel","4 = Rahmen":PRINT "2 = Seite","5 = Ende":PRINT "3 = Zeile"
460CURSOR 20,3:INPUT M
470ON M GOTO 500 ,490 ,600 ,620 ,630
480GOTO 440
490S=1:GOTO 440
500CLS :INPUT "Titel: ";T$(0)
510POKE 12348,16
520X=INT (LEN T$(0)/37.5)+1
530IF Z+X>12 GLCURSOR (0,-330):GOSUB 650
540IF K CLEAR K:GOTO 560
550CIRCLE (15,-35-Z*24),5,S,0,360,1,120
560GLCURSOR (30,-41-Z*24):COLOR 0,7:LPRINT "P";LEFT$ (T$(0),37)
570IF X>1 GLCURSOR (30,-65-Z*24):LPRINT "P";MID$ (T$(0),38,37)
580IF X>2 GLCURSOR (30,-89-Z*24):LPRINT "P";RIGHT$ (T$(0),(LEN T$(0)-74)
590Z=Z+X:GOTO 440
600IF Z+1=13 GLCURSOR (0,-330):GOSUB 650
610GLCURSOR (30,-41-Z*24):K=1:GOTO 500
620GLCURSOR (0,-330)GOSUB 650 :GOTO 440
630CLS :GLCURSOR (0,-400):LPRINT CHR$ &1B+"@"
640END
650SORGN :Z=0
660LLINE (0,-15)-(480,-315),0,0,B:POKE &FB20,0:LLINE (480,-330)-(0,-330),1
670RETURN


Dokumentation ansehen
Programmspeicher-Image laden



Zur Übersichtstabelle



Home
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!