Sharp PC1360

Navigation: Flugvorbereitung - Listing

Dokumentation ansehen/laden
Programmspeicher-Image laden

10	"N" CLEAR :WAIT 0:DEGREE :USING "####"
20	CLS :PRINT "Kennzeichen :":INPUT "D - ";K$
30	IF LEN K$<>4 GOTO 20
40	CLS :PRINT "Rechtweisender Kurs :":PRINT " Grad":CURSOR 0,1:INPUT R
50	CLS :PRINT "Reisegeschwindigkeit :":PRINT " km/h":CURSOR 0,1:INPUT V
55	IF V=0 CURSOR 0,1:PRINT " knts":CURSOR 0,1:INPUT V:V=V*1.852
60	CLS :PRINT "Treibstoffverbrauch :":PRINT " Liter / Std":CURSOR 0,1:INPUT T
70	CLS :PRINT "Windrichtung :":PRINT " Grad":CURSOR 0,1:INPUT W
80	CLS :PRINT "Windgeschwindigkeit :":PRINT " km/h":CURSOR 0,1:INPUT U
90	IF U=0 CURSOR 0,1:PRINT " knts":CURSOR 0,1:INPUT U:U=U*1.852
100	CLS :PRINT "Flugstrecke :":PRINT " km":CURSOR 0,1:INPUT S
110	CLS
120	L=ASN (SIN (W-R)*U/V)
130	M=R+L
140	IF SIN L=0 LET X=V-U*COS (R-W): GOTO 160
150	X=SIN (M-W)*U/-SIN L
160	IF X<=0 BEEP 2:PRINT "Flug bei diesen Windver-haeltnissen nicht durch-fuehrbar!":END
170	Z=S/X
180	Y=T*Z
190	Z=DMS Z
200	M=INT (M+3.5)
210	GOSUB 420
220	RESTORE 450 :READ A
230	FOR I=1 TO A:READ J$
240	IF K$=J$ LET I=A:Q=1
250	NEXT I
260	IF Q GOTO 310
270	PRINT "MwWK : Grad":CURSOR 11,0:PRINT MDF M
280	PRINT "Deviation : Grad":CURSOR 13,1:INPUT D
290	CLS
300	GOTO 350
310	RESTORE K$
320	N=M/15
330	FOR I=1 TO N:READ D:NEXT I:READ E
340	D=D+(D-E)*(N-INT N)
350	M=M-D:GOSUB 420
360	PRINT "Kompasskurs : Grad":CURSOR 13,0:PRINT M
370	PRINT "Treibstoff : Liter":CURSOR 13,1:PRINT MDF Y
380	PRINT "Grundgeschw.: km/h":CURSOR 13,2:PRINT MDF X
390	USING "###":WAIT
400	PRINT "Flugzeit : ";MDF Z;" h";MDF ((Z-INT Z)*100)
410	CLS :END
420	IF M>360 LET M=M-360
430	IF M<=0 LET M=M+360
440	RETURN
450	DATA 1,"KBAY"
460	"KBAY" DATA 5,-3,4,2,1,-3,-1,2,6,6,1,2,4,0,-4,-5,-1,0,3,5,1,1,1,1,5

Dokumentation ansehen/laden
Programmspeicher-Image laden

Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!