Sharp PC1360 Taschencomputer
 

 Sharp PC1360

E12-Widerstandscode - Listing


Dokumentation ansehen
Programmspeicher-Image laden


10 "V" CLEAR :CLS :DIM C$(0)*14,F$(2)*7
20 WAIT 0:PRINT "Code oder Wert :":INPUT C$(0)
30 L=LEN C$(0)
40 W=VAL C$(0)
50 IF W=0 THEN 440
60 FOR I=2 TO L
70 H$=MID$ (C$(0),I,1)
80 IF H$="K" OR H$="k" LET E=3:I=L:GOTO 110
90 IF H$="M" LET E=6:I=L:GOTO 110
100 IF H$="m" LET E=-3:I=L:GOTO 110
110 NEXT I
120 E=E+INT LOG W:W=W/10^INT LOG W
130 RESTORE 290
140 READ R,S:IF R<W AND S<W THEN 140
150 IF S-W<W-R LET R=S
160 IF R=10 LET R=1:E=E+1
170 I=0:ON INT R GOSUB 320 ,330 ,340 ,350 ,360 ,370 ,380 ,390 ,400
180 I=1:ON 1+(R-INT R)*10 GOSUB 310 ,320 ,330 ,340 ,350 ,360 ,370 ,380 ,390 ,400
190 E=E-1
200 I=2:ON E+1 GOSUB 310 ,320 ,330 ,340 ,350 ,360 ,370 ,380 ,390
210 IF E=-1 LET F$(2)="Gold"
220 IF E=-2 LET F$(2)="Silber"
230 IF E>8 OR E<-2 CLS :PRINT C$(0);" - Widerstand ist":PRINT "nicht verfuegbar !":END
240 B=INT (E/3):E=E-B*3
250 IF B<0 LET E=E-3:GOSUB 410
260 ON B+1 GOSUB 410 ,420 ,430
270 PRINT C$(0):PRINT F$(0):PRINT F$(1):WAIT :PRINT F$(2),"(E12-Reihe)"
280 END
290 DATA 1,1.1,1.2,1.3,1.5,1.6,1.8,2,2.2,2.4,2.7,3,3.3,3.6,3.9,4.3,4.7
300 DATA 5.1,5.6,6.2,6.8,7.5,8.2,9.1,10,10
310 F$(I)="Schwarz":RETURN
320 F$(I)="Braun":RETURN
330 F$(I)="Rot":RETURN
340 F$(I)="Orange":RETURN
350 F$(I)="Gelb":RETURN
360 F$(I)="Gruen":RETURN
370 F$(I)="Blau":RETURN
380 F$(I)="Violett":RETURN
390 F$(I)="Grau":RETURN
400 F$(I)="Weiss":RETURN
410 C$(0)=STR$ (R*10*10^E)+" Ohm =":RETURN
420 C$(0)=STR$ (R*10*10^E)+" k-Ohm =":RETURN
430 C$(0)=STR$ (R*10*10^E)+" M-Ohm =":RETURN
440 IF L=14 OR L=11 LET S=3:GOTO 465
450 IF L=10 OR (L=8 AND ASC MID$ (C$(0),3,1)>64) LET S=2:GOTO 465
460 PRINT "Eingabefehler !":GOTO 20
465 N=INT ((L+1)/S)
470 RESTORE MID$ (C$(0),1,2)
480 READ R:R=R*10^(N-3)
490 RESTORE MID$ (C$(0),S+1,2)
500 READ A:R=R+A*10^(N-4)
510 IF N=5 RESTORE MID$ (C$(0),2*S+1,2):READ A:R=R+A
520 RESTORE MID$ (C$(0),(N-2)*S+1,2)
530 READ E:R=R*10^E
540 RESTORE MID$ (C$(0),(N-1)*S+1,2)+"T":READ T
550 CLS :PRINT C$(0);" =":PRINT STR$ R;" Ohm +/- ";STR$ T;" %"
555 PRINT STR$ (R-T*R/100);" ... ";STR$ (R+T*R/100);" Ohm"
560 END
570 "SC"DATA 0
580 "BR"DATA 1
590 "RO"DATA 2
600 "OR"DATA 3
610 "GE"DATA 4
620 "GR"DATA 5
630 "BL"DATA 6
640 "VI"DATA 7
650 "GA"DATA 8
660 "WE"DATA 9
670 "SIT"DATA 10
680 "GOT"DATA 5
690 "SCT"DATA 20
700 "BRT"DATA 1
710 "ROT"DATA 2
720 "GAT"DATA 30
730 " T"DATA 20


Dokumentation ansehen
Programmspeicher-Image laden



Zur Übersichtstabelle



Home
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!