Sharp PC1360 Taschencomputer
 

 Sharp PC1360

Display Grafik Editor - Listing

Dokumentation ansehen
Programmspeicher-Image laden

10"G" CLS :CLEAR :WAIT 0:F=1
20P=POINT (X,Y)
30I$=INKEY$ :IF I$ GOTO 90
40PSET (X,Y),X
50ON P+1 GOTO 60 ,70
60PRESET (X,Y):GOTO 80
70PSET (X,Y)
80GOTO 30
90BEEP 1,8,40:ON VAL I$ GOTO 110 ,140 ,160 ,190 ,20 ,210 ,230 ,260 ,280
100GOTO 300
110IF X>0 LET X=X-1
120IF Y<31 LET Y=Y+1
130GOTO 300
140IF Y<31 LET Y=Y+1
150GOTO 300
160IF X<149 LET X=X+1
170IF Y<31 LET Y=Y+1
180GOTO 300
190IF X>0 LET X=X-1
200GOTO 300
210IF X<149 LET X=X+1
220GOTO 300
230IF X>0 LET X=X-1
240IF Y>0 LET Y=Y-1
250GOTO 300
260IF Y>0 LET Y=Y-1
270GOTO 300
280IF X<149 LET X=X+1
290IF Y>0 LET Y=Y-1
300IF M GOSUB 450
310IF ASC I$=13 GOSUB 450 :GOTO 20
320IF I$="M" LET M=NOT M+2:GOTO 20
330IF I$="W" LET F=2:GOTO 20
340IF I$="S" LET F=1:GOTO 20
350IF I$="X" LET F=3:GOTO 20
360IF I$="I" LINE (0,0)-(149,31),X,BF:GOTO 20
370IF I$="F" GOSUB 490 :GOTO 20
380IF I$="R" GOSUB 560 :GOTO 20
390IF I$="T" GOSUB 620 :GOTO 20
400IF I$="E" WAIT :GPRINT :CLS :END
410IF I$="C" GOTO 690
420IF I$="L" GOSUB 910 :GOTO 20
430IF I$="B" GOTO 1100
440GOTO 20
450"PSET" ON F GOTO 460 ,470 ,480
460PSET (X,Y):RETURN
470PRESET (X,Y):RETURN
480PSET (X,Y),X:RETURN
490"FELD"IF D=0 LET D=1:U=X:V=Y:RETURN
500D=0
510ON F GOTO 520 ,530 ,540
520LINE (U,V)-(X,Y),S,BF:RETURN
530LINE (U,V)-(X,Y),R,BF:RETURN
540LINE (U,V)-(X,Y),X,BF
550RETURN
560"RAHMEN" IF D=0 LET D=1:U=X:V=Y:RETURN
570D=0
580ON F GOTO 590 ,600 ,610
590LINE (U,V)-(X,Y),S,B:RETURN
600LINE (U,V)-(X,Y),R,B:RETURN
610LINE (U,V)-(X,Y),X,B:RETURN
620"TEXT" CURSOR INT (X/6),INT (Y/7)
630I$=INKEY$
640IF I$="" THEN 630
650IF ASC I$=13 BEEP 1,39,50:RETURN
660PRINT I$;
670BEEP 1,39,50
680GOTO 630
690"C" ERASE C
700DIM C(3,149)
710FOR I=0 TO 3
720FOR J=0 TO 149
730FOR K=0 TO 7
740IF POINT (J,I*8+K) LET C(I,J)=C(I,J)+2^K
750NEXT K:GCURSOR (J,I*8+7):GPRINT NOT C(I,J)+256
760NEXT J:NEXT I
770BEEP 2:CLS
780PRINT "A (usgabe des Codes)":PRINT "S (peichern)":PRINT "H (ardcopy)"
790INPUT "D (isplaybild) ? ";S$
800IF S$="D" OR S$="S" OR S$="A" OR S$="H" GOTO S$
810GOTO 780
820"D" WAIT 0:CLS :PRINT "N (eues Bild)":INPUT "A (ltes Bild) ? ";S$
830IF S$="N" CLS :GOTO 20
840"H" CLS:FOR I=0 TO 3:FOR J=0 TO 149
850GCURSOR (J,I*8+7)
860GPRINT C(I,J)
870NEXT J:NEXT I
880IF S$="H" GOTO 1170
890WAIT :GPRINT
900WAIT 0:GOTO 20
910"LINIE"IF L=0 LET L=1:W=X:Z=Y:RETURN
920L=0
930ON F GOTO 940 ,950 ,960
940LINE (W,Z)-(X,Y),S:RETURN
950LINE (W,Z)-(X,Y),R:RETURN
960LINE (W,Z)-(X,Y),X:RETURN
970"A" PRINT =LPRINT :WAIT 0
980FOR I=0 TO 3:FOR J=0 TO 149
990PRINT STR$ C(I,J)+";";
1000IF ASC INKEY$ =13 GOTO 1000
1010NEXT J:NEXT I
1020PRINT =PRINT
1030GOTO 780
1040"S" INPUT "Filename : ";N$
1050WAIT :PRINT "CE-140F o.k.? ":WAIT 0
1060OPEN "X:"+N$+".DGE" FOR OUTPUT AS #2
1070PRINT #2,C(*)
1080CLOSE
1090GOTO 780
1100"BILD" CLS :INPUT "Filename : ";N$
1110WAIT :PRINT "CE-140F o.k.? ":WAIT 0
1120ERASE C:DIM C(3,149)
1130OPEN "X:"+N$+".DGE" FOR INPUT AS #3
1140INPUT #3,C(*)
1150CLOSE #3
1160GOTO 780
1170"DRUCK" GPRINT
1180LPRINT CHR$ &1B+"@"
1190GRAPH :LLINE (0,0)-(450,-96),0,0,B
1200FOR J=0 TO 31 STEP 2:FOR I=0 TO 149
1210IF POINT (I,J) LLINE (I*3,-J*3)-(I*3+3,-J*3-3),0,0,B:PAINT 10
1220NEXT I
1230K=J+1
1240FOR I=149 TO 0STEP -1
1250IF POINT (I,K) LLINE (I*3,-K*3)-(I*3+3,-K*3-3),0,0,B:PAINT 10
1260NEXT I
1270NEXT J
1280LTEXT :LF 5
1290LPRINT CHR$ &1B+"@"
1300CLS :GOTO 780

Dokumentation ansehen
Programmspeicher-Image laden


Zur Übersichtstabelle



Home
Falls diese Seite ohne Navigationsleiste angezeigt wird, aktivieren Sie Javascript oder klicken Sie hier!